実験記録　No.02 : AutoItでURLEncode

XMLHttpRequestでデータのやりとりをしたい場合、URLEncodeが必要な場合があるのでAutoItでできないかと探したらAutoItのフォーラムにURLEncodeのコードがあった。
しかしよく見てみるとマルチバイト文字に対応していない・・。
仕方ないのでUTF-8でのURLEncode/Decodeを自分で書いてみた。

#cs ----------------------------------------------------------------------------
 AutoIt Version: 3.3.6.1
 Author:         H. Tsubota

 Script Function:
    URL Encode/Decode UTF-8 (Unicode Support, application/x-www-form-urlencoded)
#ce ----------------------------------------------------------------------------

$test = "実験記録 NO.02"
$test = URLEncode( $test )
ConsoleWrite($test& @CRLF)
$test = URLDecode ( $test  )
ConsoleWrite($test& @CRLF)

Func URLEncode( $str )
    Local $ret = ""
    For $i =1 To StringLen( $str )
        $char = StringMid( $str, $i, 1)
        $code = AscW ($char)
        switch $code
            case 32 ; WSpace
                $ret &= "+"
            case 45 to 46 ; - .
                $ret &= $char
            case 48 to 57 ; 0-9    
                $ret &= $char
            case 65 to 90 ; A-Z
                $ret &= $char
            case 95 ; _
                $ret &= $char
            case 97 to 122 ; a-z
                $ret &= $char
            case 126 ; ~    
                $ret &= $char
            case else
                If $code <= 127 Then
                    ; code <= 7bit >> 0b0*******
                    $ret = "%" & Hex( $code, 2 )
                ElseIf $code <= 2047 Then
                    ; 8bit<=  code <=11bit  >> 0b110***** 0b10******
                    $c1 = BitOR( BitAND (BitShift($code, 6),  0x1F ),  0xC0)
                    $c2 = BitOR(BitAND ($code, 0x3F ), 0x80)
                    $ret &= "%" & Hex( $c1, 2 )
                    $ret &= "%" & Hex( $c2, 2 )
                ElseIf $code <= 65535 Then
                    ; 12bit<=  code <=16bit  >> 0b1110**** 0b10****** 0b10******
                    $c1 = BitOR(BitAND (BitShift($code, 12),  0x0F ), 0xE0)
                    $c2 = BitOR(BitAND (BitShift($code, 6),  0x3F ), 0x80)
                    $c3 = BitOR(BitAND ($code, 0x3F ), 0x80)
                    $ret &= "%" & Hex( $c1, 2 )
                    $ret &= "%" & Hex( $c2, 2 )
                    $ret &= "%" & Hex( $c3, 2 )
                ElseIf $code <= 1114111 Then
                    ; 17bit<=  code <=21bit  >> 0b11110*** 0b10****** 0b10****** 0b10******
                    $c1 = BitOR(BitAND (BitShift($code, 18),  0x07 ), 0xF0)
                    $c2 = BitOR(BitAND (BitShift($code, 12),  0x3F ), 0x80)
                    $c3 = BitOR(BitAND (BitShift($code, 6),  0x3F ), 0x80)
                    $c4 = BitOR(BitAND ($code, 0x3F ), 0x80)
                    $ret &= "%" & Hex( $c1, 2 )
                    $ret &= "%" & Hex( $c2, 2 )
                    $ret &= "%" & Hex( $c3, 2 )
                    $ret &= "%" & Hex( $c4, 2 )
                EndIf
        endswitch
    Next
    return $ret
EndFunc

Func URLDecode( $str )
    Local $ret = ""
    
    $i = 1
    While $i <= StringLen( $str )    
        $char = StringMid( $str, $i, 1)
        switch Asc( $char )
            case 43 ; +
                $ret &= " "
                $i += 1
            case 45 to 46 ; - .
                $ret &= $char
                $i += 1
            case 48 to 57 ; 0-9    
                $ret &= $char
                $i += 1
            case 65 to 90 ; A-Z
                $ret &= $char
                $i += 1
            case 95 ; _
                $ret &= $char
                $i += 1
            case 97 to 122 ; a-z
                $ret &= $char
                $i += 1
            case 126 ; ~    
                $ret &= $char
                $i += 1
            case 37 ; %
                $c1 = Dec(StringMid( $str, $i+1, 2))
                If $c1<= 127  Then
                    ; code <= 7bit >> 0b0*******
                    $ret &= ChrW($c1)
                    $i += 3
                ElseIf 192 <= $c1 And $c1<= 223 Then    
                    ; 8bit<=  code <=11bit  >> 0b110***** 0b10******
                    $c1 = BitXOR( Dec(StringMid( $str, $i+1, 2)), 0xC0)
                    $c2 = BitXOR(Dec(StringMid( $str, $i+4, 2)), 0x80)
                    $code = BitOR (BitShift($c1, -6), $c2)
                    $ret &= ChrW($code)
                    $i += 6
                ElseIf 224 <= $c1 And $c1<= 239 Then
                    ; 12bit<=  code <=16bit  >> 0b1110**** 0b10****** 0b10******
                    $c1 = BitXOR(Dec(StringMid( $str, $i+1, 2)), 0xE0)
                    $c2 = BitXOR(Dec(StringMid( $str, $i+4, 2)), 0x80)
                    $c3 = BitXOR(Dec(StringMid( $str, $i+7, 2)), 0x80)
                    $code = BitOR (BitShift($c1, -6), $c2)
                    $code = BitOR (BitShift($code, -6), $c3)
                    $ret &= chrW($code)
                    $i += 9                    
                ElseIf $c1>= 240 And $c1<= 247 Then
                    ; 17bit<=  code <=21bit  >> 0b11110*** 0b10****** 0b10****** 0b10******
                    $c1 = BitXOR(Dec(StringMid( $str, $i+1, 2)), 0xF0)
                    $c2 = BitXOR(Dec(StringMid( $str, $i+4, 2)), 0x80)
                    $c3 = BitXOR(Dec(StringMid( $str, $i+7, 2)), 0x80)
                    $c4 = BitXOR(Dec(StringMid( $str, $i+10, 2)), 0x80)
                    $code = BitOR (BitShift($c1, -6), $c2)
                    $code = BitOR (BitShift($code, -6), $c3)    
                    $code = BitOR (BitShift($code, -6), $c4)    
                    $ret &= ChrW($code)
                    $i += 12
                EndIf    
      endswitch
    WEnd    
    return $ret
EndFunc

参考にしたのはこのサイト。
非エンコード文字のあたりはちゃんとした資料を見てないため漏れがあるかもしれないので使用する場合は注意が必要。

関連:
AutoItでIEを自動操作
AutoIt v3 ドキュメント日本語訳プロジェクト

タグ：: #AutoIt; #URL; #Encode; #Decode; #エンコード; #デコード

名前
	情報を記憶評価顔星

実験記録 No.02

AutoItでURLEncode

「AutoIt」カテゴリの最新記事

コメントする

実験記録　No.02